$ TEST No IC18 - HEMISPHERE WITH POINT LOADS
$
$ Short description:
$ The system is generated in such a manner, so as to allow the calculation of
$ several different element meshes consisting of quad-elements. The following
$ element meshes are investigated: 4x4 elements (mesh partitioning 2),
$ 8x8 elements (mesh partitioning 4) and 16x16 elements (mesh partitioning 8).
$ The calculation is made with the program ASE.
$
$ Results:
$ - Comparative value x-displacement in point A: Desired value 0.185 m analytical,
$   0.1838 m fine mesh (8x8) 8-node quad-element
$   values obtained with ASE:
$               4x4:  0.12006 m
$               8x8:  0.17978 m
$             16x16:  0.18492 m
$
$   further results of the ASE-calculation: values in m
$   Displacements
$
$         Point A = Point 1       Point B = Point 9              Point C
$         Vx         Vz           Vx          Vy          Vz     Vy
$         --------------------------------------------------------------------
$   4x4   0.12006    0.06356      0.03953     -0.03953    0.0    -0.12006
$   8x8   0.17978    0.08965      0.06036     -0.06036    0.0    -0.17978
$ 16x16   0.18492    0.09069      0.06244     -0.06244    0.0    -0.18492
$
$ Theory  0.185                                                  -0.185
$
$ Bench-
$ mark    0.1838     Print error  0.0628      -0.0628     0.0
$                    round 0.09
$
$ Note print error in the result lists:  false   Vz in point  1   0.
$                                        correct Vz in point  1   round 0.09 m
$                                        (see also boundary conditions)

PROG GENF urs:4
HEAD TEST No IC18 - HEMISPHERE WITH POINT LOADS
TXB Element mesh with 2,4,8 elements symmetric about point G
SYST SPAC
MAT  1 E 68.25e6 MUE 0.3
GRP 0 T 0.04
$
LET#4 8                          $ mesh partitioning (<9!), only 1,2,4,8 are possible
LET#9 10.                      $ Radius
$
$ DEFINE ALL ELEMENTS WITH A CUBE
NODE 101   #9    0    0
     109   #9   #9    0
     909    0   #9    0
     181   #9    0   #9
     189   #9   #9   #9
     981    0    0   #9
     989    0   #9   #9
MESH 101 109 189 181 #4 #4 MNO 1
     181 189 989 981 #4 #4 MNO 1
     109 909 989 189 #4 #4 MNO 1
$
NODE (101 181  (181-101)/#4) FIX PYYM ; (181 981 (981-181)/#4) ==
     (909 989  (989-909)/#4) FIX PXXM ; (981 989 (989-981)/#4) ==
      981          FIX F
$      101,909,981      FIX XPYM,YPXM,F
$
$
$BLOCK BEG1
$ SUB-PROGRAM FOR NODE GENERATION IN A COORDINATE THIRD
$ NODE COORDINATES WITH NONLINEAR INCREMENT ROTATION
$ #1,#2,#3 = NODE NUMBER ON AXIS + INCREMENTS
LET#10   0,45/#4      $ initial value + increment phi-Y
LOOP #4+1
LET#20   0,45/#4      $ initial value + increment phi-Z
LOOP #4+1
LET#90 SQR(TAN(#10)**2+TAN(#20)**2)
LET#91 ATN(#90)
LET#92 COS(#91),0.0
LOOP #91-0.001 ; LET#93 SIN(#91)/#90 ; ENDLOOP -1
$ knoten:
    #1    #9*#92 #9*TAN(#20)*#93 #9*TAN(#10)*#93
$
LET#20 #20+#21
LET#1  #1+#3
ENDLOOP
LET#10 #10+#11
LET#1  #1-#3*(#4+1)+#2
ENDLOOP
$BLOCK END1
$
LET#1 101,(181-101)/#4,(109-101)/#4      $ node number + increments of X-sector
NODE  NO  X  Y  Z
$BLOCK SET1
$
LET#1 909,(109-909)/#4,(989-909)/#4      $ node number + increments of Y-sector
NODE  NO  Y  Z  X
$BLOCK SET1
$
LET#1 981,(989-981)/#4,(181-981)/#4      $ node number + increments of Z-sector
NODE  NO  Z  X  Y
$BLOCK SET1
$
END

PROG ASE urs:5
HEAD TEST No IC18 - HEMISPHERE WITH POINT LOADS
TXB Element mesh with 2,4,8 elements symmetric about point G
ECHO ERIN AUS
LC 1
LOAD 101 PX 2.
LOAD 909 PY -2.
END


PROG WING urs:3
SIZE LP 0
VIEW STAN 1 1 1 NEGZ
STRU 1 1
LOAD FULL
COLO C5 6001 6001 6001 6001 ; DEFO 1 10.0 ; STRU 0 0 ; AND
COLO C5 1002 1002 1002 1002 ; DEFO 0 ; STRU 0 0
NODE UX UNIT 1000 SCHH 0.1 ND 4
NODE UY UNIT 1000 SCHH 0.1 ND 4
NODE UZ UNIT 1000 SCHH 0.1 ND 4
NODE U UNIT 1000 SCHH 0.1 ND 4
QUAD SXM SCHH 0.1 STYP NODE
QUAD SYM SCHH 0.1 STYP NODE
END
END