SOFiSTiK Forum

It is currently Thu Jun 20, 2019 1:44 am

All times are UTC




Post new topic Reply to topic  [ 20 posts ]  Go to page Previous  1, 2
Author Message
PostPosted: Tue Jun 11, 2019 8:30 am 
Offline

Joined: Tue Jun 20, 2006 9:32 am
Posts: 439
Hallo,

ich denke,
Code:
+SYS
ist nicht in der Lage iter Anweisungen umzusetzen.

Desweiteren würde ich unterschiedliche Systeme (unterschiedlichen Krümmungsradien) nicht in EINER CDB abhandeln.

Alternativ geht vielleicht folgendes:
Code:
#DEFINE BLOCK
+PROG AQUA
KOPF 1. Material, Querschnitt und globale Variable
UNIT 5
NORM 'DIN' 'en1993-2005' COUN 49 $ CAT 'B' WIND '2' SNOW '1' WCAT 'B' UNIT 5
sto#nn $(STEP)

sto#r 40+20*#nn  $ Krümmungsradius mittel-Achse
sto#b 18  $ Breite der Brücke
sto#L 60  $ Länge der Brücke mittellinie
sto#h 6 $ Höhe der LSW
sto#ra #r+#b/2  $Krümmungsradius in außenwand
sto#ri #r-#b/2  $ krümmungsradius in innenwand
sto#alpha #L/(2*#r) $ halbe Öffnungswinkel
sto#La 2*#ra*#alpha   $ Bogenlänge außen Gurt
sto#Li 2*#ri*#alpha   $ Bogenlänge innen Gurt

sto#sina sin(#alpha*180/3.1415927)
sto#cosa cos(#alpha*180/3.1415927)

sto#npf 7 $ Anzahl der Pfosten/QT
sto#deltafi 2*#alpha/(#npf-1)   $  winkel zwischen 2 punkte in Gurt

STAH 1   S '355MT' BEZ "=S 355 MT (EN 1993)"
ARBL EPS GEBR SIG 1.100000[-]
ARBL EPS BRUC SIG 1.100000[-] TYP  EXT
HMAT 1 TYP FOUR NSP 0 A 1

BETO 2    C '30' GAM 0 TYPR    B BEZ "=C 30/37 (EN 1992)"
ARBL EPS GEBR SIG 1.500000[-] TYP  LIM
ARBL EPS BRUC SIG 1.500000[-]
ARBL EPS RECH SIG -1.300000[-]
HMAT 2 TYP FOUR NSP 0.030000 A 1
STEU
STEU BEWQ 0
STEU FACE -1
STEU REFD 0
STEU STYP  FEM
STEU  SQS 16
STEU PLAS 1

QNR  1 MNR 1 MBW 0 ZSYM NEIN BTYP DRUC BEZ "UG"
QW   IT 100[o/o]
BLEC '0100' YA -200 ZA -700 YE 200 ZE -700 D 10 MNR 1
BLEC '0200' YA 200 ZA -700 YE 200 ZE 700 D 10 MNR 1
BLEC '0300' YA 200 ZA 700 YE -200 ZE 700 D 10 MNR 1
BLEC '0400' YA -200 ZA 700 YE -200 ZE -700 D 10 MNR 1
STEU
STEU BEWQ 0
STEU FACE -1
STEU REFD 0
STEU STYP  FEM
STEU  SQS 16
STEU PLAS 1

QC nr 2 D 508 T 20 MNR 1 MBW 0  AY 100[o/o] AZ 100[o/o] BTYP DRUC BEZ "OG"  IT 100[o/o]
STEU
STEU BEWQ 0
STEU FACE -1
STEU REFD 0
STEU STYP  FEM
STEU  SQS 16
STEU PLAS 1

QNR  3 MNR 1 MBW 0 ZSYM NEIN BTYP DRUC BEZ "Pfosten"
QW   IT 100[o/o]
BLEC '0300' YA 200 ZA 200 YE -200 ZE 200 D 15 MNR 1
BLEC '0400' YA -200 ZA 200 YE -200 ZE -200 D 15 MNR 1
BLEC '0100' YA -200 ZA -200 YE 200 ZE -200 D 15 MNR 1
BLEC '0200' YA 200 ZA -200 YE 200 ZE 200 D 15 MNR 1

QNR  5 MNR 1 MBW 0 ZSYM NEIN BTYP BEAM BEZ "QT-stahl"
QW   IT 100[o/o]

BLEC '0100' YA -200 ZA -700 YE 200 ZE -700 D 20 MNR 1
BLEC '0200' YA 200 ZA -700 YE 200 ZE 700 D 15 MNR 1
BLEC '0300' YA 200 ZA 700 YE -200 ZE 700 D 15 MNR 1
BLEC '0400' YA -200 ZA 700 YE -200 ZE -700 D 15 MNR 1
BLEC '0500' YA 0 ZA -870 YE 7500 ZE -870 D 300 MNR 2
BLEC '0800' YA -2.84217E-14 ZA -870 YE -7500 ZE -870 D 300 MNR 2
LNAH '0700' YA 200 ZA -700 YE 0 ZE -870 D 20 MNR 1
STEU
STEU BEWQ 0
STEU FACE -1
STEU REFD 0
STEU STYP  FEM
STEU  SQS 16
STEU PLAS 1
ende

+PROG sofimshc
KOPF 2. Modellierung
UNIT 5
SYST RAUM GDIV 100000 GDIR POSZ
STEU TOPO 0
STEU TOLG WERT  0.010000[m]
STEU MESH 2
STEU HMIN WERT  0.25[m]
STEU FEIN WERT -0.325
STEU PROG WERT  1.238
STEU EFAK WERT  1.3986

$ mittel-Achse der Brücke


$ Achse der OG außen innen ,UG außen innen
gax id 2  typc arc      $ 'UG-aus' Achse
gaxb X1 #ra*#cosa #ra*#sina 0 X2 #ra*#cosa -#ra*#sina -6  r -#ra

gax id 3  typc arc     $ 'UG-in'  Achse
gaxb X1 #ri*#cosa #ri*#sina 0 X2 #ri*#cosa -#ri*#sina -6  r -#ri

gax id 4 typc arc    $ 'OG-aus'  Achse
gaxb X1 #ra*#cosa #ra*#sina -6 X2 #ra*#cosa -#ra*#sina 0  r -#ra

gax id 5  typc arc   $ 'OG-in' Achse
gaxb X1 #ri*#cosa #ri*#sina -6 X2 #ri*#cosa -#ri*#sina 0  r -#ri

loop#j #npf     $ QT  Achse
let#i 21+#j
gax id #i typ lane
gaxb  x1 #ra*cos((#alpha-#j*#deltafi)*180/3.1415927) #ra*sin((#alpha-#j*#deltafi)*180/3.1415927) 0  x2 #ri*cos((#alpha-#j*#deltafi)*180/3.1415927) #ri*sin((#alpha-#j*#deltafi)*180/3.1415927) 0
endloop

$ spt kreupunkte Gurt und pfosten und QT
loop#j  #npf             $ spt in OG außen
spt nr 100+#j+1  x #ra*cos((#alpha-#deltafi*#j)*180/3.1415927) y #ra*sin((#alpha-#deltafi*#j)*180/3.1415927) z -6
endloop

loop#j #npf              $ spt in OG innen
spt nr 300+#j+1 x #ri*cos((#alpha-#deltafi*#j)*180/3.1415927) y #ri*sin((#alpha-#deltafi*#j)*180/3.1415927) z -6
endloop

loop#j  #npf             $ spt in UG außen
spt nr 500+#j+1  x #ra*cos((#alpha-#deltafi*#j)*180/3.1415927) y #ra*sin((#alpha-#deltafi*#j)*180/3.1415927) z 0
endloop

loop#j  #npf             $ spt in UG außen
spt nr 700+#j+1  x #ri*cos((#alpha-#deltafi*#j)*180/3.1415927) y #ri*sin((#alpha-#deltafi*#j)*180/3.1415927) z 0
endloop

$ Elemente
loop#j #npf  $ Element in Pfosten außen
sln nr 1000+1+#j npa 500+#j+1 npe 100+#j+1 drot -(#alpha-#deltafi*#j)*180/3.1415927 qnr 3  grp 1
endloop

loop#j #npf  $ Element in Pfosten innen
sln nr 1200+1+#j npa 700+#j+1 npe 300+#j+1 drot -(#alpha-#deltafi*#j)*180/3.1415927 qnr 3  grp 2
$ STEU HMIN WERT 0.2[m]
endloop

loop#j #npf $ Element in QT
let#i 21+#j
sln nr 1400+1+#j npa 700+#j+1 npe 500+#j+1 ref #i qnr 5 grp 11+#j
steu bsec
endloop

$ rand LSW  und UG,OG
loop#j #npf-1
sln 1601+#j npa 501+#j npe 502+#j ref 2 qnr 1 grp 3 $ UG aus
endloop

loop#j #npf-1
sln 1801+#j npa 701+#j npe 702+#j ref 3 qnr 1 grp 4 $ UG in
endloop

loop#j #npf-1
sln 2001+#j npa 101+#j npe 102+#j ref 4 qnr 2 grp 5 $ OG aus
endloop

loop#j #npf-1
sln 2201+#j npa 301+#j npe 302+#j ref 5 qnr 2 grp 6  $ OG in
endloop


loop#j #npf-1      $ LSW außen
SAR #j+1 T 30 MNR 1 MCTL 1  grp 7
STEU DELN 0
SARB aus NL 1001+#j,2001+#j,1002+#j,1601+#j
endloop

loop#j #npf-1      $ LSW innen
SAR #j+31 T 30 MNR 1 MCTL 1  grp 8
STEU DELN 0
SARB aus NL 1801+#j,1201+#j,2201+#j,1202+#j
endloop

ende

+prog sofimsha
kopf
unit 5
syst rest

knot 701  fix ppmz;  knot 701 fix mr dx #b*#cosa  dy #b*#sina  dz 0
knot 501  fix pzmz; knot 501 fix pr dx #sina  dy -#cosa dz 0 ;  knot 501 fix mr dx #b*#cosa  dy #b*#sina dz 0
knot 700+#npf  fix pxpzmz; knot 700+#npf fix mr dx #b*#cosa  dy -#b*#sina dz 0
knot 500+#npf  fix pzmz; knot 500+#npf fix pr dx #sina*(#ra+#ri)  dy (#ra-#ri)*#cosa dz 0  ;  knot 500+#npf fix mr dx #b*#cosa  dy -#b*#sina  dz 0
ende

+prog sofiload
kopf 3.Tandemsystem
ACT G   GAMU 1.35 GAMF 1.00
ACT L_T GAMU   -  0 SUP EXCL PSI0 0.75 PSI1 0.75 PSI2 0.20 PS1S    - BEZ 'TS Tandemsystem'
ACT L_U GAMU   -  0 SUP COND PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S    - BEZ 'UDL Gleichlast'
lf 21+1000*#nn   typ L_T
let#i 11+(#npf-1)/2
stel grp #i typ pzz p 600/4 a 14,16 ey 600
stel grp #i typ pzz p 600/4 a 14,16 ey -600
stel grp #i typ pzz p 400/4 a 11,13 ey 600
stel grp #i typ pzz p 400/4 a 11,13 ey -600
stel grp #i typ pzz p 200/4 a 8,10 ey 600
stel grp #i typ pzz p 200/4 a 8,10 ey -600

ende

+prog sofiload
kopf 4. UDL
loop#j #npf
lf 101+#j+1000*#nn  typ none    $ innen Fahrspur 1
 stab grp 11+#j typ pzz #L*3/#npf   $ 3kN/m^2, 5.72m breit QT, Fahrstreife 3,4,5,bordstein
 stab grp 11+#j typ pzz #L*3/#npf a 10.5 l 3   $ 6kN/m^2, 5,72m breit QT, Fahrstreife 2
 stab grp 11+#j typ pzz (#La+#L)*6/(2*#npf) a 13.5 l 3   $ 12kN/m^2, 5,72m breit QT, Fahrstreife 1
endloop

lf 201+1000*#nn  typ L_U
 loop#j #npf
 copy 101+#j+1000*#nn
 endloop


lf 202+1000*#nn  typ G  egz 1.0


lf 301+1000*#nn typ none  egz 1.35
copy 21+1000*#nn fakt 1.35
copy 201+1000*#nn fakt 1.35

lf 302+1000*#nn typ none  egz 1.0
copy 21+1000*#nn fakt 0.7
copy 201+1000*#nn fakt 0.7
ende


+prog ase
kopf 5. Lastfall Berechnen
lf alle
ende

+prog ase
kopf 6. Stabilität
syst plf 301+1000*#nn
eige neig 30 etyp beul nite - mite - lmin auto lf 401+1000*#nn
ende

+sys copy $(name).cdb $(name)-$(STEP).cdb
+sys copy $(name).plb $(name)-$(STEP).PLB
+sys del $(NAME).cdb
+sys del $(NAME).plb
#ENDDEF

#define STEP = 0
        #include BLOCK

#define STEP = 1
        #include BLOCK

#define STEP = 2
        #include BLOCK

#define STEP = 3
        #include BLOCK

#define STEP = 4
        #include BLOCK
...
...
...


_________________
Schöne Grüße

Philipp Loosmann


Top
 Profile  
 
PostPosted: Fri Jun 14, 2019 2:37 pm 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Danke schon für deine Vorschläge ;)

ich denke auch, dass Block in diesem Fall besser ist !


Top
 Profile  
 
PostPosted: Fri Jun 14, 2019 2:55 pm 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
gmay wrote:
Wenn ich mir die Eingabe so ansehe, dann geht es darum mehrere Variante durchzurechnen und auch alle Datenbanken zu speichern.

In solchen Fällen verwende ich für jede Variante eine eigene (kleine) DAT-Datei, die nur die Parameter festlegt und die Berechnung einbindet:
Code:
+prog template
kopf PARAMETER
STO#nn 1     $ Parameter festlegen
ende

$ Berechnung einfügen
#include Berechnung.dat               
Die eigentliche Eingabedatei ist "Berechnung.dat", die eine komplette Berechnung durchführt. Diese Datei ist für alle Varianten gleich und kann auch nachträglich noch verändert werden.
Die DAT-Datei enthält meist nur ein Modul template und könnte eventuell auch automatisiert erstellt werden.

Das Starten der Berechnungen erfolgt bei mir dann über eine Batchdatei:
Code:
wps -b -e system1.dat
wps -b -e system2.dat
wps -b -e system3.dat
Die Parameter sind im Sofistik-Handbuch beschrieben. Möglicherweise sind die Pfade noch anzugeben (Parameter "-s")
Alternativ kann auch sps statt wps verwendet werden.

Grüße
gmay


Danke schon! Aber habe ich nicht verstanden, was die Batchdatei ist.
Könntest du vielleicht einmal erklären?


Top
 Profile  
 
PostPosted: Mon Jun 17, 2019 7:08 am 
Offline

Joined: Tue Jun 20, 2006 9:32 am
Posts: 439
Hallo Lena,

eine Batch-Datei ist eine Stapelverarbeitungsdatei im TXT-Format, die von Windows/MS-DOS verarbeitet werden kann.
Die Endung ist .BAT oder .CMD
Damit kannst Du beispielsweise eine großen Anzahl vom Berechnungen nacheinander durchführen lassen, ohne jede Einzelberechnung starten zu müssen.

_________________
Schöne Grüße

Philipp Loosmann


Top
 Profile  
 
PostPosted: Mon Jun 17, 2019 12:21 pm 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Vielen vielen Dank!

Ihr habt mir sehr viel geholfen!


Top
 Profile  
 
Display posts from previous:  Sort by  
Post new topic Reply to topic  [ 20 posts ]  Go to page Previous  1, 2

All times are UTC


Who is online

Users browsing this forum: No registered users and 8 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
cron
Powered by phpBB® Forum Software © phpBB Group