SOFiSTiK Forum

It is currently Tue Jul 23, 2019 9:03 pm

All times are UTC




Post new topic Reply to topic  [ 20 posts ]  Go to page 1, 2  Next
Author Message
PostPosted: Fri Apr 05, 2019 10:23 am 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Kann man bei Teddy die Parameter für BLOCK durch Schleife definiert?

Ich habe ein BLOCK definiert, aber die Parameter muss ich mehr als 20 mal schreiben und sieht die code ziemlich lang aus. Gibt es eine kürzere Form dafür?

z.B. in eine Block mit mehere PROGs habe ich 2 Parameter benutzt, $(p) und $(q).
Nach dem BLOCK möchte ich z.B. $(p) und $(q) jede von 10 bis 20 definieren, aber wenn ich die $(p) und $(q) mit LOOP definiert, geht es nicht. :?: :?:
wenn ich die code sowie unten schreib, läuft es. :roller:

Brauch eure Hilfe :bounce: :bounce:

mein code:

#define BLOCK
$
...
$
#ENDDEF

#define p=10 $p=10

#define q=5
#include BlOCK

#define q=6
#include BlOCK

#define q=7
#include BlOCK

#define q=8
#include BlOCK

#define q=9
#include BlOCK

#define q=10
#include BlOCK

#define q=11
#include BlOCK

#define q=12
#include BlOCK

#define p=15 $ p=15

#define q=5
#include BlOCK

#define q=6
#include BlOCK

#define q=7
#include BlOCK

#define q=8
#include BlOCK

#define q=9
#include BlOCK

#define q=10
#include BlOCK

#define q=11
#include BlOCK

#define q=12
#include BlOCK


Top
 Profile  
 
PostPosted: Sat Apr 06, 2019 12:11 pm 
Offline

Joined: Tue Jun 20, 2006 9:32 am
Posts: 441
Hallo,

so in etwa?
Code:
#DEFINE BLOCK
<text>
p = #p   &   q = #q
</text>
#ENDDEF

+prog template urs:1
kopf
loop#i 2
        let#p 10+#i*5
        loop#k 7
                let#q 6+#k
                        #include BLOCK
        endloop
endloop
ende

_________________
Schöne Grüße

Philipp Loosmann


Top
 Profile  
 
PostPosted: Mon Apr 08, 2019 7:09 am 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Danke dir, PLoosmann !!

Das ist genau was ich brauche! :bounce: :bounce:


Top
 Profile  
 
PostPosted: Mon Apr 08, 2019 2:01 pm 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Hallo,

deine code funktioniert sehr gut!

aber wenn ich etwas ähnlich probieren möchte, kommt immer die Fehle
" +++++ Fehler Nr. 12117 ; Eingabezeile: 24
2 Loops bzw. Abfragen (IF-ENDIF) nicht beendet"
am Anfang mit sofimsha

Ich habe eine Reihe ähnliche System und möchte ich die Eigenforme und Beullasten von jede rechnen, deswegen benutze ich BLOCK,
aber wo steht meine Codebug? :?:

meine Code sind so:

Code:
#define BLOCK
+PROG AQUA
KOPF 0. material
ECHO MAT,QUER EXTR
NORM EN 1993-2005
STAH 1 S 355 BEZ 'Baustahl'
prof nr 1 HEA 300
ENDE

+prog sofimsha
KOPF 1.System Modellierung
syst 3D
knot nr 1 x 0 y #q z #p fix pxpymz
knot nr 2 x 0 y 0 z 0 fix pxpypzmz
stab nr 1 1 2 qnr 1
endloop
ende

+prog sofiload
kopf 2. Einwirkungen zentrischer Druck
lf 1 bez 'Lastfall_zentrische druck'
knot 1 typ pzz p1 -100   $zentrische Druck  in kN
ende

+prog ase
kopf 3. Berechnung
lf 1 bez 'Lastfall_zentrische druck'
ende

+prog ase urs:4
kopf 4. Eigenwerte
syst plf 1
eige neig 4 etyp beul nite - mite - lmin auto lf 100+1
ende

+sys copy $(name).cdb $(name)-#q-#p.cdb
#ENDDEF

+prog template
kopf
loop#i 2
   let#p 10+#i*5
   loop#k 7
      let#q 6+#k
      #include BLOCK
   endloop
endloop
ende



Top
 Profile  
 
PostPosted: Tue Apr 09, 2019 11:34 am 
Offline

Joined: Wed Dec 10, 2008 1:35 pm
Posts: 78
Die Fehlermeldung kommt daher, dass die im Modul "template" plötzlich ein anderes Modul, in diesem Fall "AQUA" gestartet wird. LOOP und IF funktionieren nur innerhalb eines Moduls.

Bitte auch beachten, dass alle Eingaben mit #define, #include oder ähnlichem vorab als Text ersetzt werden. Das gleiche gilt für Variablen $(var), auch diese werdeb als Text einfgefügt. Erst danach werden die einzelnen Module gestartet.
z.B. wird der Code:
Code:
#define BLOCK
txa Wert von i = #i
#enddef

prog template
kopf
loop#i 2
      #include BLOCK
endloop
ende
in diesen übersetzt:
Code:
prog template
kopf
loop#i 2
   txa Wert von i = #i
endloop
ende


Für die gewünschte Anwendung könnte eventuell eine Iteration hilfreich sein (siehe sofistik_0.pdf "Iteration über mehrere Module"):
Code:
prog TEMPLATE
STO#TARGET 0
STO#PARAM 1.0
ende

prog AQUA ITER
RCL#PARAM
QNR .... Definition Querschnitt mit #PARAM
ende

prog AQB ITER
BEME .... Bemessen und Speichern Ergebnisse
ENDE
@KEY / LET# TARGET ... Ermittle eine Zielfunktion
IF ABS(#TARGET) < 0.001
EXIT_ITERATION
ELSE
STO#PARAM new_target_value
ENDIF
ende


Grüße
gmay


Top
 Profile  
 
PostPosted: Tue Apr 09, 2019 1:25 pm 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Ach so! :shock:

Vielen vielen Dank für die Erklärung.

Dann versuche ich mal mit iteration zu realisieren.


Top
 Profile  
 
PostPosted: Tue Apr 09, 2019 1:36 pm 
Offline

Joined: Tue Jun 20, 2006 9:32 am
Posts: 441
Hallo,

oder es endet in einer kleinen Copy-Paste-Orgie :lol: :

Code:
#define BLOCK
+PROG AQUA
KOPF 0. material
ECHO MAT,QUER EXTR
NORM EN 1993-2005
STAH 1 S 355 BEZ 'Baustahl'
prof nr 1 HEA 300
ENDE

+prog sofimsha
KOPF 1.System Modellierung
syst 3D
knot nr 1 x 0 y $(q) z $(p) fix pxpymz
knot nr 2 x 0 y 0 z 0 fix pxpypzmz
stab nr 1 1 2 qnr 1
ende

+prog sofiload
kopf 2. Einwirkungen zentrischer Druck
lf 1 bez 'Lastfall_zentrische druck'
knot 1 typ pzz p1 -100   $zentrische Druck  in kN
ende

+prog ase
kopf 3. Berechnung
lf 1 bez 'Lastfall_zentrische druck'
ende

+prog ase urs:4
kopf 4. Eigenwerte
syst plf 1
eige neig 4 etyp beul nite - mite - lmin auto lf 100+1
ende

+sys copy $(name).cdb $(name)-$(q)-$(p).cdb
+sys copy $(name).plb $(name)-$(q)-$(p).plb

+sys del $(name).cdb
+sys del $(name).plb
#ENDDEF


#define p = 10
        #define q = 6
                #include BLOCK
        #define q = 7
                #include BLOCK
        #define q = 8
                #include BLOCK
        #define q = 9
                #include BLOCK
        #define q = 10
                #include BLOCK
        #define q = 11
                #include BLOCK
        #define q = 12
                #include BLOCK

#define p = 15
        #define q = 6
                #include BLOCK
        #define q = 7
                #include BLOCK
        #define q = 8
                #include BLOCK
        #define q = 9
                #include BLOCK
        #define q = 10
                #include BLOCK
        #define q = 11
                #include BLOCK
        #define q = 12
                #include BLOCK


Für Parameterstudien bestens geeignet.
Nur aufs Häkchen "Weiterrechnen bei Fehler" achten, damit alle Systeme gerechnet werden.

_________________
Schöne Grüße

Philipp Loosmann


Top
 Profile  
 
PostPosted: Tue Apr 23, 2019 11:06 am 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Danke Ploosmann!

Also es funktioniert auch ohne die Sätze:
+sys del $(name).cdb
+sys del $(name).plb

Eigentlich brauche ich viele verschiedene Werte für #q und #p einzusetzen, deswegen suche ich
eine Möglichkeit, mit LOOP zu realisieren, statt jedesmal die Werte für #p und #q zu schreiben.

Aber jetzt habe ich mit "iter" mein Wunsch realisiert. nur so mit "iter" bekomme ich nur den .cdb
von dem letzten Rechnen. andere, was ich brauche, habe ich schon bekommen.


Top
 Profile  
 
PostPosted: Wed Apr 24, 2019 7:46 am 
Offline

Joined: Tue Jun 20, 2006 9:32 am
Posts: 441
Hallo,

Quote:
Aber jetzt habe ich mit "iter" mein Wunsch realisiert. nur so mit "iter" bekomme ich nur den .cdb
von dem letzten Rechnen. andere, was ich brauche, habe ich schon bekommen.


Dazu würde ich am Ende der Schleife eine Zeile mit dem +SYS Befehl einbauen:

Code:
+SYS COPY $(name).cdb $(name)-$(Irgendwas).cdb

_________________
Schöne Grüße

Philipp Loosmann


Top
 Profile  
 
PostPosted: Mon Jun 03, 2019 8:54 am 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Hallo, PLoosmann.

Danke schon! Aber die Code

Code:
+SYS COPY $(name).cdb $(name)-$(Irgendwas).cdb


kann nicht mit iter gleichzeitig funktionieren, wobei mein Code ist,

Code:
+SYS COPY $(name).cdb $(name)-$(#d)-$(#b).cdb   iter 30


warum kann diese code nicht mit iter laufen?


Top
 Profile  
 
PostPosted: Mon Jun 03, 2019 12:38 pm 
Offline

Joined: Tue Jun 20, 2006 9:32 am
Posts: 441
Hallo,

ich denke, dass die Variablen #d und #b nur INNERHLAB eines Modules abrufbar sind.

Vielleicht funktioniert es ja mit DEFINE im entsprechenden Modul
Code:
+prog ....
...
...
#DEFINE ZIEL=$(name)-#d-#b
ENDE

+SYS COPY $(name).cdb $(ZIEL).cdb   iter 30

_________________
Schöne Grüße

Philipp Loosmann


Top
 Profile  
 
PostPosted: Tue Jun 04, 2019 8:32 am 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Danke !

Aber der ganze "sys copy" Satz wird alle rote markiert, inklusiv "iter 30"

und es kann nicht in iter durchgeführt.


You do not have the required permissions to view the files attached to this post.


Top
 Profile  
 
PostPosted: Tue Jun 04, 2019 10:58 am 
Offline

Joined: Tue Jun 20, 2006 9:32 am
Posts: 441
Hallo,

laden Sie doch bitte die Teddy Datei mal hier hoch.
Kann ja in abgespeckter Form sein.

Ich würde dann nochmal drüber schauen

_________________
Schöne Grüße

Philipp Loosmann


Top
 Profile  
 
PostPosted: Thu Jun 06, 2019 8:29 am 
Offline

Joined: Fri Apr 05, 2019 9:49 am
Posts: 11
Vielen Dank !

Was mache ich ist: Stabilität_Untersuchung von gekrümmter Trogbrücke mit unterschiedlichen Krümmungsradien
Deswegen mache ich Radius als Parameter und lass es "iter" mit verschiedenen Radien und brauche ich die .cdb Dokument, um die Beulenforme zu schauen.

und mein Code ist so:

Code:
+prog template
kopf  sto#nn
sto#nn 0
ende


+PROG AQUA  iter 5
KOPF 1. Material, Querschnitt und globale Variable
UNIT 5
NORM 'DIN' 'en1993-2005' COUN 49 $ CAT 'B' WIND '2' SNOW '1' WCAT 'B' UNIT 5
sto#nn #nn+1

sto#r 40+20*#nn  $ Krümmungsradius mittel-Achse
sto#b 18  $ Breite der Brücke
sto#L 60  $ Länge der Brücke mittellinie
sto#h 6 $ Höhe der LSW
sto#ra #r+#b/2  $Krümmungsradius in außenwand
sto#ri #r-#b/2  $ krümmungsradius in innenwand
sto#alpha #L/(2*#r) $ halbe Öffnungswinkel
sto#La 2*#ra*#alpha   $ Bogenlänge außen Gurt
sto#Li 2*#ri*#alpha   $ Bogenlänge innen Gurt

sto#sina sin(#alpha*180/3.1415927)
sto#cosa cos(#alpha*180/3.1415927)

sto#npf 7 $ Anzahl der Pfosten/QT
sto#deltafi 2*#alpha/(#npf-1)   $  winkel zwischen 2 punkte in Gurt

STAH 1   S '355MT' BEZ "=S 355 MT (EN 1993)"
ARBL EPS GEBR SIG 1.100000[-]
ARBL EPS BRUC SIG 1.100000[-] TYP  EXT
HMAT 1 TYP FOUR NSP 0 A 1

BETO 2    C '30' GAM 0 TYPR    B BEZ "=C 30/37 (EN 1992)"
ARBL EPS GEBR SIG 1.500000[-] TYP  LIM
ARBL EPS BRUC SIG 1.500000[-]
ARBL EPS RECH SIG -1.300000[-]
HMAT 2 TYP FOUR NSP 0.030000 A 1
STEU
STEU BEWQ 0
STEU FACE -1
STEU REFD 0
STEU STYP  FEM
STEU  SQS 16
STEU PLAS 1

QNR  1 MNR 1 MBW 0 ZSYM NEIN BTYP DRUC BEZ "UG"
QW   IT 100[o/o]
BLEC '0100' YA -200 ZA -700 YE 200 ZE -700 D 10 MNR 1
BLEC '0200' YA 200 ZA -700 YE 200 ZE 700 D 10 MNR 1
BLEC '0300' YA 200 ZA 700 YE -200 ZE 700 D 10 MNR 1
BLEC '0400' YA -200 ZA 700 YE -200 ZE -700 D 10 MNR 1
STEU
STEU BEWQ 0
STEU FACE -1
STEU REFD 0
STEU STYP  FEM
STEU  SQS 16
STEU PLAS 1

QC nr 2 D 508 T 20 MNR 1 MBW 0  AY 100[o/o] AZ 100[o/o] BTYP DRUC BEZ "OG"  IT 100[o/o]
STEU
STEU BEWQ 0
STEU FACE -1
STEU REFD 0
STEU STYP  FEM
STEU  SQS 16
STEU PLAS 1

QNR  3 MNR 1 MBW 0 ZSYM NEIN BTYP DRUC BEZ "Pfosten"
QW   IT 100[o/o]
BLEC '0300' YA 200 ZA 200 YE -200 ZE 200 D 15 MNR 1
BLEC '0400' YA -200 ZA 200 YE -200 ZE -200 D 15 MNR 1
BLEC '0100' YA -200 ZA -200 YE 200 ZE -200 D 15 MNR 1
BLEC '0200' YA 200 ZA -200 YE 200 ZE 200 D 15 MNR 1

QNR  5 MNR 1 MBW 0 ZSYM NEIN BTYP BEAM BEZ "QT-stahl"
QW   IT 100[o/o]

BLEC '0100' YA -200 ZA -700 YE 200 ZE -700 D 20 MNR 1
BLEC '0200' YA 200 ZA -700 YE 200 ZE 700 D 15 MNR 1
BLEC '0300' YA 200 ZA 700 YE -200 ZE 700 D 15 MNR 1
BLEC '0400' YA -200 ZA 700 YE -200 ZE -700 D 15 MNR 1
BLEC '0500' YA 0 ZA -870 YE 7500 ZE -870 D 300 MNR 2
BLEC '0800' YA -2.84217E-14 ZA -870 YE -7500 ZE -870 D 300 MNR 2
LNAH '0700' YA 200 ZA -700 YE 0 ZE -870 D 20 MNR 1
STEU
STEU BEWQ 0
STEU FACE -1
STEU REFD 0
STEU STYP  FEM
STEU  SQS 16
STEU PLAS 1
ende

+PROG sofimshc iter 5
KOPF 2. Modellierung
UNIT 5
SYST RAUM GDIV 100000 GDIR POSZ
STEU TOPO 0
STEU TOLG WERT  0.010000[m]
STEU MESH 2
STEU HMIN WERT  0.25[m]
STEU FEIN WERT -0.325
STEU PROG WERT  1.238
STEU EFAK WERT  1.3986

$ mittel-Achse der Brücke


$ Achse der OG außen innen ,UG außen innen
gax id 2  typc arc      $ 'UG-aus' Achse
gaxb X1 #ra*#cosa #ra*#sina 0 X2 #ra*#cosa -#ra*#sina -6  r -#ra

gax id 3  typc arc     $ 'UG-in'  Achse
gaxb X1 #ri*#cosa #ri*#sina 0 X2 #ri*#cosa -#ri*#sina -6  r -#ri

gax id 4 typc arc    $ 'OG-aus'  Achse
gaxb X1 #ra*#cosa #ra*#sina -6 X2 #ra*#cosa -#ra*#sina 0  r -#ra

gax id 5  typc arc   $ 'OG-in' Achse
gaxb X1 #ri*#cosa #ri*#sina -6 X2 #ri*#cosa -#ri*#sina 0  r -#ri

loop#j #npf     $ QT  Achse
let#i 21+#j
gax id #i typ lane
gaxb  x1 #ra*cos((#alpha-#j*#deltafi)*180/3.1415927) #ra*sin((#alpha-#j*#deltafi)*180/3.1415927) 0  x2 #ri*cos((#alpha-#j*#deltafi)*180/3.1415927) #ri*sin((#alpha-#j*#deltafi)*180/3.1415927) 0
endloop

$ spt kreupunkte Gurt und pfosten und QT
loop#j  #npf             $ spt in OG außen
spt nr 100+#j+1  x #ra*cos((#alpha-#deltafi*#j)*180/3.1415927) y #ra*sin((#alpha-#deltafi*#j)*180/3.1415927) z -6
endloop

loop#j #npf              $ spt in OG innen
spt nr 300+#j+1 x #ri*cos((#alpha-#deltafi*#j)*180/3.1415927) y #ri*sin((#alpha-#deltafi*#j)*180/3.1415927) z -6
endloop

loop#j  #npf             $ spt in UG außen
spt nr 500+#j+1  x #ra*cos((#alpha-#deltafi*#j)*180/3.1415927) y #ra*sin((#alpha-#deltafi*#j)*180/3.1415927) z 0
endloop

loop#j  #npf             $ spt in UG außen
spt nr 700+#j+1  x #ri*cos((#alpha-#deltafi*#j)*180/3.1415927) y #ri*sin((#alpha-#deltafi*#j)*180/3.1415927) z 0
endloop

$ Elemente
loop#j #npf  $ Element in Pfosten außen
sln nr 1000+1+#j npa 500+#j+1 npe 100+#j+1 drot -(#alpha-#deltafi*#j)*180/3.1415927 qnr 3  grp 1
endloop

loop#j #npf  $ Element in Pfosten innen
sln nr 1200+1+#j npa 700+#j+1 npe 300+#j+1 drot -(#alpha-#deltafi*#j)*180/3.1415927 qnr 3  grp 2
$ STEU HMIN WERT 0.2[m]
endloop

loop#j #npf $ Element in QT
let#i 21+#j
sln nr 1400+1+#j npa 700+#j+1 npe 500+#j+1 ref #i qnr 5 grp 11+#j
steu bsec
endloop

$ rand LSW  und UG,OG
loop#j #npf-1
sln 1601+#j npa 501+#j npe 502+#j ref 2 qnr 1 grp 3 $ UG aus
endloop

loop#j #npf-1
sln 1801+#j npa 701+#j npe 702+#j ref 3 qnr 1 grp 4 $ UG in
endloop

loop#j #npf-1
sln 2001+#j npa 101+#j npe 102+#j ref 4 qnr 2 grp 5 $ OG aus
endloop

loop#j #npf-1
sln 2201+#j npa 301+#j npe 302+#j ref 5 qnr 2 grp 6  $ OG in
endloop


loop#j #npf-1      $ LSW außen
SAR #j+1 T 30 MNR 1 MCTL 1  grp 7
STEU DELN 0
SARB aus NL 1001+#j,2001+#j,1002+#j,1601+#j
endloop

loop#j #npf-1      $ LSW innen
SAR #j+31 T 30 MNR 1 MCTL 1  grp 8
STEU DELN 0
SARB aus NL 1801+#j,1201+#j,2201+#j,1202+#j
endloop

ende

+prog sofimsha iter 5
kopf
unit 5
syst rest

knot 701  fix ppmz;  knot 701 fix mr dx #b*#cosa  dy #b*#sina  dz 0
knot 501  fix pzmz; knot 501 fix pr dx #sina  dy -#cosa dz 0 ;  knot 501 fix mr dx #b*#cosa  dy #b*#sina dz 0
knot 700+#npf  fix pxpzmz; knot 700+#npf fix mr dx #b*#cosa  dy -#b*#sina dz 0
knot 500+#npf  fix pzmz; knot 500+#npf fix pr dx #sina*(#ra+#ri)  dy (#ra-#ri)*#cosa dz 0  ;  knot 500+#npf fix mr dx #b*#cosa  dy -#b*#sina  dz 0
ende

+prog sofiload iter 5
kopf 3.Tandemsystem
ACT G   GAMU 1.35 GAMF 1.00
ACT L_T GAMU   -  0 SUP EXCL PSI0 0.75 PSI1 0.75 PSI2 0.20 PS1S    - BEZ 'TS Tandemsystem'
ACT L_U GAMU   -  0 SUP COND PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S    - BEZ 'UDL Gleichlast'
lf 21+1000*#nn   typ L_T
let#i 11+(#npf-1)/2
stel grp #i typ pzz p 600/4 a 14,16 ey 600
stel grp #i typ pzz p 600/4 a 14,16 ey -600
stel grp #i typ pzz p 400/4 a 11,13 ey 600
stel grp #i typ pzz p 400/4 a 11,13 ey -600
stel grp #i typ pzz p 200/4 a 8,10 ey 600
stel grp #i typ pzz p 200/4 a 8,10 ey -600

ende

+prog sofiload iter 5
kopf 4. UDL
loop#j #npf
lf 101+#j+1000*#nn  typ none    $ innen Fahrspur 1
 stab grp 11+#j typ pzz #L*3/#npf   $ 3kN/m^2, 5.72m breit QT, Fahrstreife 3,4,5,bordstein
 stab grp 11+#j typ pzz #L*3/#npf a 10.5 l 3   $ 6kN/m^2, 5,72m breit QT, Fahrstreife 2
 stab grp 11+#j typ pzz (#La+#L)*6/(2*#npf) a 13.5 l 3   $ 12kN/m^2, 5,72m breit QT, Fahrstreife 1
endloop

lf 201+1000*#nn  typ L_U
 loop#j #npf
 copy 101+#j
 endloop


lf 202+1000*#nn  typ G  egz 1.0


lf 301+1000*#nn typ none  egz 1.35
copy 21 fakt 1.35
copy 201 fakt 1.35

lf 302+1000*#nn typ none  egz 1.0
copy 21 fakt 0.7
copy 201 fakt 0.7
ende


+prog ase iter 5
kopf 5. Lastfall Berechnen
lf alle
ende

+prog ase iter 5
kopf 6. Stabilität
syst plf 301
eige neig 30 etyp beul nite - mite - lmin auto lf 401+1000*#nn
ende

+sys copy $(name).cdb $(name)-$(#nn).cdb   iter 5



Top
 Profile  
 
PostPosted: Tue Jun 11, 2019 7:52 am 
Offline

Joined: Wed Dec 10, 2008 1:35 pm
Posts: 78
Wenn ich mir die Eingabe so ansehe, dann geht es darum mehrere Variante durchzurechnen und auch alle Datenbanken zu speichern.

In solchen Fällen verwende ich für jede Variante eine eigene (kleine) DAT-Datei, die nur die Parameter festlegt und die Berechnung einbindet:
Code:
+prog template
kopf PARAMETER
STO#nn 1     $ Parameter festlegen
ende

$ Berechnung einfügen
#include Berechnung.dat               
Die eigentliche Eingabedatei ist "Berechnung.dat", die eine komplette Berechnung durchführt. Diese Datei ist für alle Varianten gleich und kann auch nachträglich noch verändert werden.
Die DAT-Datei enthält meist nur ein Modul template und könnte eventuell auch automatisiert erstellt werden.

Das Starten der Berechnungen erfolgt bei mir dann über eine Batchdatei:
Code:
wps -b -e system1.dat
wps -b -e system2.dat
wps -b -e system3.dat
Die Parameter sind im Sofistik-Handbuch beschrieben. Möglicherweise sind die Pfade noch anzugeben (Parameter "-s")
Alternativ kann auch sps statt wps verwendet werden.

Grüße
gmay


Top
 Profile  
 
Display posts from previous:  Sort by  
Post new topic Reply to topic  [ 20 posts ]  Go to page 1, 2  Next

All times are UTC


Who is online

Users browsing this forum: Exabot [Bot] and 7 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
cron
Powered by phpBB® Forum Software © phpBB Group