SOFiSTiK Forum

It is currently Wed Nov 13, 2019 12:27 pm

All times are UTC




Post new topic Reply to topic  [ 3 posts ] 
Author Message
 Post subject: Tasks Looping.
PostPosted: Wed Sep 26, 2018 11:40 am 
Offline

Joined: Mon Jul 23, 2018 11:26 am
Posts: 7
Does anybody know if there is any chance to calculate a few tasks in loops like in the example below?

Loop 5
Prog template with variables to specific load cases
Prog maxima
Prog aqb
Endloop

For me it's like "must be" but I cannot figure this out. The way I wrote it obviously doesn't work, but i wanted you to see what i want to achieve.

Anybody?


Top
 Profile  
 
 Post subject: Re: Tasks Looping.
PostPosted: Fri Oct 05, 2018 8:00 am 
Offline

Joined: Tue Jun 20, 2006 9:32 am
Posts: 446
Hello,

a small example:

Code:
#define BLOCK
+sys del $(NAME).CDB
+sys del $(PROF)_$(H).plb
+sys del $(PROF)_$(H).cdb

+prog aqua
head
norm din en1993-2005
stee 1 s 235
prof 1 $(PROF) $(H) MNO 1
end

+prog sofimsha
head
syst 2d
node 1  0   0 fix pxpy
     5  2.5 0
     11 5   0 fix py
     mesh 1 11 DIV 10

beam fit 1 11 NCS 1
end

+prog sofiload
head
act g   ; lc 1 DLY 1.00 TITL 'G'   ; node 5 pyy 1
act s   ; lc 2          TITL 'S'   ; node 5 pyy 1
act q_A ; lc 3          TITL 'Q'   ; node 5 pyy 1
act w   ; lc 4          TITL 'W.1' ; node 5 pyy 1 ; node 5 mzz  1
act w   ; lc 4          TITL 'W.2' ; node 5 pyy 1 ; node 5 mzz -1
end

+prog star2
head
ctrl I
lc ALL
end

+prog maxima
head
echo node v
comb 1 rare
        act g,s,q_a,w
        supp 1 max node uy
end

+sys copy $(NAME).plb $(PROF)_$(H).plb
+sys copy $(NAME).cdb $(PROF)_$(H).cdb
#ENDDEF

#define PROF = IPE
#define H    = 300
#include BLOCK

#define PROF = HEA
#define H    = 200
#include BLOCK

#define PROF = HEB
#define H    = 200
#include BLOCK


_________________
Schöne Grüße

Philipp Loosmann


Top
 Profile  
 
 Post subject: Re: Tasks Looping.
PostPosted: Mon Oct 15, 2018 8:47 am 
Offline

Joined: Mon Jul 23, 2018 11:26 am
Posts: 7
PLoosmann,
that's brilliant. That's exactly what I wanted to achieve. Thank you very much.


Top
 Profile  
 
Display posts from previous:  Sort by  
Post new topic Reply to topic  [ 3 posts ] 

All times are UTC


Who is online

Users browsing this forum: Google [Bot], MSN [Bot] and 10 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
Powered by phpBB® Forum Software © phpBB Group