SOFiSTiK Forum

<TEXT>

Um die Überhöhungen ansehen zu können muss jeder Bauabschnitt zuerst gewichtslos aufgebracht werden.
Und das Eigengewicht wird dann erst im nächste BA aufgebracht.

Um den ersten überhöhten Bauabschnitt sehen zu können muss im Wingraf  der Ergebnissumfang auf Alle gestellt werden.

</TEXT>



!#!Kapitel Systemerzeugung
-prog aqua urs:1
kopf  Material
norm OEN EN1992  coun at cat B
beto 1 C 30
stah 2 s 550b
stah 3 S 355
ende


-prog aqua urs:4
kopf  Querschnitte
steu rest 2 $ Daten aus Datenbasis hehalten
qnr nr 1 mnr 3  bez '4 x RT50 DN40mm'
krei 2 r 0.01
qnr nr 2 mnr 3  bez 'HEB700-S235'
prof nr 1 typ heb z1 700 zm 350
ende


-prog sofimshc urs:2
Kopf System
Echo voll nein
syst art raum gdiv 0 gdir posz
steu mesh 2
steu hmin 0.4


spt     nr      x       y       z   fix
        1       0       0       0   pxpy
        2       0       5       0
        3       10       0       0   py
        4       10       5       0
        5       20      0       0
        6       20      5       0
        7       30      0       0
        8       30      5       0

sln       nr      npa     npe  fix
          1       1       2    pz
          2       3       4    pz
          3       5       6    pz
          4       7       8    pz
          5       1       3
          6       3       5
          7       5       7
          8       2       4
          9       4       6
          10      6       8


grup nr 1 base 100000
grup nr 2 base 200000
grup nr 3 base 300000


sar nr 1  mnr 1 mbw 2 grp 1 qref unte T 0.5
sarb typ aus nl 1,2,5,8

sar nr 2  mnr 1 mbw 2 grp 2 qref unte T 0.5
sarb typ aus nl 2,3,6,9

sar nr 3  mnr 1 mbw 2 grp 3 qref unte T 0.5
sarb typ aus nl 3,4,7,10



ende





-prog sofiload urs:3
Kopf
Echo voll
lf 1 bez 'Feld 1'
area ref qgrp nr 1 typ pzz p1 100
lf 2 bez 'Feld 2'
area ref qgrp nr 2 typ pzz p1 100
lf 3 bez 'Feld 3'
area ref qgrp nr 3 typ pzz p1 100


ende

!#!Kapitel ASe

-prog ase urs:5
kopf Berechnung
Steu solv 4
lf 1,2,3
ende




!#!Kapitel CSM Lineare Erstrechnung

-prog csm urs 500 urs:80
kopf bauzustaende Line
echo voll nein
$steu ase text 'steu warn 43'
ba      nr      typ     t       bez
        10      g_1     -       'Feld 1'
        20      g_1     -       'Feld 2'
        30      g_1     -       'Feld 3'



grup    nr      iba1    wbis    t0
        1       10      -
        2       20      -
        3       30      -


$lf      nr      typ     iba1    wbis
$        1       b       25      29


ende

-apply $(NAME)_csm.dat


!#!Kapitel  Maxima

-prog template urs:76
kopf Definitionen
sto#KBquax 1
sto#KBquas 1
sto#KBbsct 0
sto#KBstab 0
sto#KBqbed 0
sto#KBknot 0
sto#KBknow 0
sto#KBfede 0
sto#KBkine 0
sto#Echotabu 1
$ Kombinationslastfallnumer Base
Sto#BaseKB 20000
Ende


-prog maxima urs:330
#define Text= desi
STO#KBNr 1100
Kopf $(Text)
Echo voll nein
komb Extr stan base #KBNr+#BaseKB
lf  (1 3 1) fakt 1.35 typ cond
lf   4030   fakt 1.35 typ g
if #KBquax==1; supp etyp qua* zust n,m,vx,vy          extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
if #KBquas==1; supp etyp qua* zust s                  extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
if #KBbsct==1; supp etyp bsct zust n,vy,vz,mt,my,mz   extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
if #KBstab==1; supp etyp stab zust n,vy,vz,mt,my,mz   extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
if #KBqbed==1; supp etyp qbed zust p                  extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
if #KBknot==1; supp etyp knot zust p,mx,my,mz         extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
if #KBknow==1; supp etyp knot zust ux,uy,uz           extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
if #KBfede==1; supp etyp fede zust p,pt,ptx,pty,ptz,m extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
if #KBkine==1; supp etyp kine zust p,mx,my,mz         extr mami bez $(Text);if #Echotabu==1; Echo tabu ja; endif; endif
ende


!#!Kapitel Bewehrung lt DESI Überlagerung

-PROG BEMESS urs:515
KOPF Voreinstellung
ECHO PARA,BEME,ZUS VOLL
steu bruc
steu lfb 1
dust nein
GEOM - HU 20 DHU 10 HO 20 DHO 10;para - asu 0 0 aso 0 0
GEOM - HU 20 DHU 10 HO 20 DHO 10;para nrg (1 3 1)  asu 0 0 aso 0 0
ENDE



-PROG BEMESS urs:217
KOPF Bewehrung aus ULS ermitteln
ECHO PARA,BEME,ZUS VOLL
steu bruc $ Wichtig da sonst die Lastfälle noch faktorisiert werden
steu lfb 1
Steu warn 66
mat minq 0 $ Wichtig. Sonst 20
dust nein
$GEOM - HU 20 DHU 10 HO 20 DHO 10;
$RICH  oben 0 unte 0
$para - asu 2.8 2.8 aso 2.8 2.8
lf  (21101 21116 1)  fakt 1
ENDE


!#!Kapitel CSM Nichtlineare Zweitrechnung

-prog csm urs 500 urs:6
kopf bauzustaende Nonl
echo voll nein

STEU PROB NONL w2 400
STEU NMAT JA
Steu krag 0
steu ase text 'steu solv 4'
steu ase text 'BEWQ lfb 1 lfbs 10'


ba      nr      typ     t       bez
        05      g_1     -       'Beton in Schalung'  $ Diese Abschnitte
        10      g_1     -       'Feld 1'
        15      g_1     -       'Beton in Schalung'
        20      g_1     -       'Feld 2'
        25      g_1     -       'Beton in Schalung'
        30      g_1     -       'Feld 3'



grup    nr      iba1    wbis    t0 ibag
        1       05      -       -  10
        2       15      -       -  20
        3       25      -       -  30


$lf      nr      typ     iba1    wbis
$        4       b       05      05

uebe ba 30 mode line

ende

-apply $(NAME)_csm.dat